📄
играProgram listing

Connect 4

© Barry Allen январь 1984 BBC

«Четыре в ряд» против компьютера: бросайте фишки в столбцы, чтобы первым собрать линию из четырёх.

237 lines BBC BASIC
  1. 1REM CONNECT 4
  2. 2REM (C) BARRY ALLEN, Jan 1984
  3. 3*KEY10O.|MRUN|M
  4. 4*FX220,0
  5. 5DIMC%(7),DZ%(7),PR%(7),DY%(7),DX%(7),DO%(7),A%(7),AX%(7),AA%(7,7),AS%(7),AT%(7),B%(7),CO%(7),CC%(7)
  6. 6DIMX%(4),Y%(4),CS%(2),OPWIN%(7)
  7. 7R$=CHR$(129):G$=CHR$(130):Y$=CHR$(131):B$=CHR$(132):M$=CHR$(133):C$=CHR$(134):W$=CHR$(135):FO$=CHR$(136):FF$=CHR$(137)
  8. 8GR$=CHR$(145):GG$=CHR$(146):GY$=CHR$(147):GB$=CHR$(148):GM$=CHR$(149):GC$=CHR$(150):GW$=CHR$(151)
  9. 9DH$=CHR$(141):NB$=CHR$(157):CD$=CHR$(10):CU$=CHR$(11):CA$=CHR$(9):CB$=CHR$(8)
  10. 10MO.7
  11. 11V.23;8202;0;0;0;
  12. 12CLS:P.TAB(1,8)Y$DH$"CONNECT 4 COPYRIGHT B.E.ALLEN":P.TAB(1)Y$DH$"CONNECT 4 COPYRIGHT B.E.ALLEN"
  13. 13P.TAB(3,13)C$"DO YOU REQUIRE INSTRUCTIONS":P.TAB(10)C$"PRESS 'Y' OR 'N'"
  14. 14IFGE.<>"Y"TH.16
  15. 15PROCDISCFALL:PROCWINLINE
  16. 16DR%=0:CA%=1:CS%(1)=22:CS%(2)=7:Z%=0:LO%=0:WI%=0
  17. 17X%(1)=1:Y%(1)=0:X%(2)=1:Y%(2)=1:X%(3)=0:Y%(3)=1:X%(4)=1:Y%(4)=-1
  18. 18CLS:CA%=3-CA%:CO%=CA%:IFCA%=2TH.FC%=1EL.FC%=2+RND(3)
  19. 19F.I%=1TO7:OPWIN%(I%)=0:N.
  20. 20KO%=0:Z%=0
  21. 21PROCBOARD
  22. 22P.W$CHR$(152)"Press a number or 'R' to resign"
  23. 23V.30
  24. 24P.TAB(30,4)Y$CHR$(152)"YOU WIN"
  25. 25P.TAB(30,5)Y$CHR$(152)"VICTORY"
  26. 26P.TAB(30,6)W$CHR$(152)"GOOD TRY"
  27. 27P.TAB(30,7)W$CHR$(152)FO$"HO! HO!"
  28. 28P.TAB(30,8)C$CHR$(152)FO$"CRAFTY"
  29. 29F.I%=1TO7:C%(I%)=1:AA%(I%,1)=1:N.
  30. 30W%=0:F.I%=1TO7:F.J%=2TO7:AA%(I%,J%)=0:N.:N.
  31. 31P.TAB(30,14)W$"SCORE"
  32. 32P.TAB(30,16)GC$CHR$(115)W$;LO%
  33. 33P.TAB(30,18)GY$CHR$(255)W$;WI%
  34. 34P.TAB(30,20)W$"DRAW ";DR%
  35. 35CO%=3-CO%:IFCO%=1TH.CC$=GC$EL.CC$=GY$
  36. 36P.TAB(30,12)CC$CHR$(CO%*140-25)" TURN"
  37. 37IFCO%=2TH.GOS.60:Z%=0:G.47
  38. 38P.TAB(1,23)" ";
  39. 39*FX15,0
  40. 40K%=GET-48:IFK%=34TH.WI%=WI%+1:G.18
  41. 41IFK%<1 OR K%>7 TH.40
  42. 42IFFC%=1TH.PROCFIRSTDISC
  43. 43W%=0
  44. 44IFC%(K%)=8TH.40
  45. 45IFOPWIN%(K%)=1TH.LO%=LO%+1:Z%=1:PROCLOSE:P.TAB(31,4)" ":G.52
  46. 46P.TAB(1,23)CHR$(152);
  47. 47IFW%=2TH.WI%=WI%+1:PROCVICTORY:P.TAB(31,5)" ":T%=INKEY(500):G.52
  48. 48V.7
  49. 49AA%(K%,C%(K%))=CS%(CO%):IFC%(K%)<7TH.AA%(K%,C%(K%)+1)=1
  50. 50T%=5+RND(3)
  51. 51IFW%=1TH.P.TAB(31,T%)" ":V.7:F.I=1TO5000:N.
  52. 52C%(K%)=C%(K%)+1:IFC%(K%)=8TH.KO%=KO%+1
  53. 53F.I%=0TO8-C%(K%):P.TAB(4*K%-2,3*I%+1)CC$CHR$(CO%*140-25):IFI%=8-C%(K%)TH.55
  54. 54F.J%=1TO500:N.:P.TAB(4*K%-1,3*I%+1)" "
  55. 55N.
  56. 56IFW%=2ORZ%=1TH.F.I=1TO19000:N.:G.18
  57. 57IFKO%=7TH.P.TAB(30,3)W$;"DRAW":F.I%=1TO9000:N.:DR%=DR%+1:G.18
  58. 58IFW%=1TH.P.TAB(31,T%)CHR$(152)
  59. 59G.35
  60. 60PL%=0:ADD%=0
  61. 61F.I%=1TO7
  62. 62OPWIN%(I%)=0
  63. 63DZ%(I%)=0:PR%(I%)=0:DY%(I%)=0:DX%(I%)=0:DO%(I%)=0
  64. 64IFC%(I%)=8TH.115
  65. 65DZ%(I%)=0:PR%(I%)=0:DY%(I%)=0:DX%(I%)=0:DO%(I%)=0
  66. 66UP%=C%(I%)+ADD%
  67. 67IFUP%=8TH.128
  68. 68F.L%=1TO4
  69. 69S%=1:F%=4
  70. 70ONL%GOS.131,135,140,144
  71. 71IFS%>F%TH.109
  72. 72A%(1)=0:A%(2)=0:A%(3)=0:A%(4)=0
  73. 73F.M%=S%TOF%
  74. 74AX%(M%)=0
  75. 75F.N%=1TO4
  76. 76IFM%=N%TH.79
  77. 77X%=I%+(N%-M%)*X%(L%):Y%=UP%+(N%-M%)*Y%(L%)
  78. 78AX%(M%)=AX%(M%)+AA%(X%,Y%)
  79. 79N.
  80. 80IFAX%(M%)=30ORAX%(M%)=36ORAX%(M%)=29ORAX%(M%)=51TH.C%=1:G.99
  81. 81IFAX%(M%)=24TH.C%=10:DY%(I%)=DY%(I%)+1:G.99
  82. 82IFAX%(M%)=21A.ADD%=0TH.K%=I%:W%=2:M%=F%:N.:L%=4:N.:I%=7:N.:G.129
  83. 83IFAX%(M%)=21A.ADD%=1TH.C%=6000:G.105
  84. 84IFAX%(M%)=3TH.C%=22:G.99
  85. 85IFAX%(M%)=9TH.C%=21:G.99
  86. 86IFAX%(M%)=2TH.C%=20:G.99
  87. 87IFAX%(M%)=66TH.C%=90000:W%=1-ADD%:G.105
  88. 88IFL%=3A.I%<>FC%TH.AX%(M%)=AX%(M%)+1
  89. 89IFAX%(M%)=15TH.C%=33:DO%(I%)=DO%(I%)+1:G.99
  90. 90IFAX%(M%)=8TH.C%=32:G.99
  91. 91IFAX%(M%)=1TH.C%=31:G.99
  92. 92IFAX%(M%)=0TH.C%=30:G.99
  93. 93IFAX%(M%)=7TH.C%=41:G.99
  94. 94IFAX%(M%)=44TH.C%=150:DZ%(I%)=DZ%(I%)+1:G.99
  95. 95IFAX%(M%)=22TH.C%=40:G.99
  96. 96IFAX%(M%)=23TH.C%=23:G.99
  97. 97IFAX%(M%)=14TH.C%=160:G.99
  98. 98IFAX%(M%)=45TH.C%=11:DX%(I%)=DX%(I%)+1
  99. 99IFDZ%(I%)>0A.DY%(I%)>0TH.C%=210
  100. 100IFDX%(I%)>1TH.C%=250
  101. 101IFDX%(I%)>2TH.C%=300
  102. 102IFDX%(I%)>0A.DZ%(I%)>0TH.C%=400
  103. 103IFDZ%(I%)>1TH.C%=800
  104. 104IFDO%(I%)>1TH.C%=1000
  105. 105A%(M%)=C%
  106. 106N.
  107. 107NN%=4:GOS.164
  108. 108PR%(I%)=PR%(I%)+B%
  109. 109N.
  110. 110IFPR%(I%)>=90000TH.OPWIN%(I%)=OPWIN%(I%)+1+ADD%
  111. 111IFADD%=1A.AS%(CO%(1))>=10000TH.PL%=1:G.128
  112. 112IFADD%=1A.PR%(I%)>=10000TH.122
  113. 113IFADD%=1A.PR%(I%)<=AS%(I%)+150TH.128
  114. 114IFADD%=1A.PR%(I%)>AS%(I%)+150TH.122
  115. 115N.
  116. 116F.X%=1TO7
  117. 117AT%(X%)=PR%(X%):B%(X%)=X%
  118. 118N.
  119. 119NN%=7:GOS.150
  120. 120F.X%=1TO7:AS%(X%)=AT%(X%):CO%(X%)=B%(X%):N.
  121. 121ADD%=1
  122. 122PL%=PL%+1
  123. 123IFAS%(CO%(PL%))<>0TH.127
  124. 124F.IP%=1TOPL%-1:CC%(IP%)=CO%(IP%):A%(CC%(IP%))=PR%(CO%(IP%)):N.
  125. 125NN%=PL%-1:GOS.170
  126. 126K%=ID%:G.129
  127. 127I%=CO%(PL%):G.65
  128. 128K%=CO%(PL%)
  129. 129OPWIN%(K%)=(OPWIN%(K%)A.2)-1
  130. 130R.
  131. 131REMSUB[
  132. 132IFI%>4TH.S%=I%-3
  133. 133IFI%<4TH.F%=I%
  134. 134R.
  135. 135IFI%>UP%A.I%>4TH.S%=I%-3:G.137
  136. 136IFUP%>4TH.S%=UP%-3
  137. 137IFI%<UP%A.I%<4TH.F%=I%:G.139
  138. 138IFUP%<4TH.F%=UP%
  139. 139R.
  140. 140REMSUBUP
  141. 141IFUP%>4TH.S%=UP%-3
  142. 142IFUP%<4TH.F%=UP%
  143. 143R.
  144. 144REM SUB FOR DOWN
  145. 145IFI%+UP%<=8A.UP%<4TH.S%=5-UP%:G.147
  146. 146IFI%+UP%>8A.I%>4TH.S%=I%-3
  147. 147IFI%+UP%>=8A.UP%>4TH.F%=8-UP%:G.149
  148. 148IFI%+UP%<8A.I%<4TH.F%=I%
  149. 149R.
  150. 150REMINTERCHANGE
  151. 151F.T%=1TO NN%-1
  152. 152IFAT%(B%(T%))>=AT%(B%(T%+1))TH.162
  153. 153C%=B%(T%)
  154. 154B%(T%)=B%(T%+1)
  155. 155B%(T%+1)=C%
  156. 156F.S%=T%TO1S.-1
  157. 157IFAT%(B%(S%))>=AT%(B%(S%+1))TH.161
  158. 158C%=B%(S%)
  159. 159B%(S%)=B%(S%+1)
  160. 160B%(S%+1)=C%
  161. 161N.
  162. 162N.
  163. 163R.
  164. 164B%=A%(1)
  165. 165F.V%=2TONN%
  166. 166IFB%>=A%(V%)TH.168
  167. 167B%=A%(V%)
  168. 168N.
  169. 169R.
  170. 170BB%=A%(CC%(1)):ID%=CC%(1)
  171. 171IFNN%=1TH.176
  172. 172F.V%=2TONN%
  173. 173IFBB%<=A%(CC%(V%))TH.175
  174. 174BB%=A%(CC%(V%)):ID%=CC%(V%)
  175. 175N.
  176. 176R.
  177. 177DEFPROCVICTORY
  178. 178SO.1,-15,97,10
  179. 179SO.1,-15,105,10
  180. 180SO.1,-15,89,10
  181. 181SO.1,-15,41,10
  182. 182SO.1,-15,69,20
  183. 183E.
  184. 184DEFPROCLOSE
  185. 185F.L%=1TO10
  186. 186F.P%=50TO150
  187. 187SO.17,-15,P%,2
  188. 188N.
  189. 189N.
  190. 190E.
  191. 191DEFPROCBOARD
  192. 192CLS
  193. 193F.I=1TO7
  194. 194P.GR$"7```7```7```7```7```7```7```5"
  195. 195F.J=1TO8:P.GR$"5 ";:N.:P.
  196. 196F.J=1TO8:P.GR$"5 ";:N.:P.
  197. 197N.
  198. 198P.GR$"````````````````````````````!"
  199. 199P.M$" 1 2 3 4 5 6 7"
  200. 200E.
  201. 201DEFPROCDISCFALL
  202. 202CLS
  203. 203P.TAB(0,7)Y$"YOS AND THE COMPUTER TAKE TURNS TO"
  204. 204P.Y$"PLACE DISCS IN ANY ONE OF THE SEVEN"
  205. 205P.Y$"COLUMNS. THE DISCS WILL ALWAYS DROP"
  206. 206P.Y$"AS FAR DOWN AS THEY CAN."
  207. 207P.C$"PRESS RETURN TO SEE HOW."
  208. 208IFGET<>13TH.208
  209. 209PROCBOARD
  210. 210CO%=1:F.I%=1TO7:C%(I%)=1:N.
  211. 211REP.:V.7
  212. 212K%=RND(7):CO%=3-CO%:IFCO%=1TH.CC$=GC$EL.CC$=GY$
  213. 213C%(K%)=C%(K%)+1:IFC%(K%)=8TH.212
  214. 214F.I%=0TO8-C%(K%):P.TAB(4*K%-2,3*I%+1)CC$CHR$(CO%*140-25):IFI%=8-C%(K%)TH.216
  215. 215F.J%=1TO500:N.:P.TAB(4*K%-1,3*I%+1)" "
  216. 216N.
  217. 217U.C%(4)=4
  218. 218E.
  219. 219DEFPROCWINLINE
  220. 220CLS
  221. 221P.TAB(0,7)Y$"THE AIM OF THE GAME IS TO GET FOUR"
  222. 222P.Y$"OF YOUR DISCS IN LINE VERTICALLY,"
  223. 223P.Y$"HORIZONTALLY OR DIAGONALLY."
  224. 224P.C$"PRESS RETURN TO SEE HOW."
  225. 225IFGET<>13TH.225
  226. 226PROCBOARD
  227. 227P." PRESS RETURN TO CONTINUE"
  228. 228K%=6:F.I%=1TO4
  229. 229P.TAB(4*K%-2,3*I%+1)CC$CHR$(255):N.
  230. 230I%=6:F.K%=1TO4
  231. 231P.TAB(4*K%-2,3*I%+1)CC$CHR$(255):N.
  232. 232F.I%=2TO5:P.TAB(4*I%-2,3*I%+1)CC$CHR$(255):N.
  233. 233IFGET<>13TH.233
  234. 234E.
  235. 235DEFPROCFIRSTDISC
  236. 236IFK%<7 A. K%>1 TH.FC%=K% EL. FC%=4
  237. 237E.